#!/usr/bin/perl -wT

# Copyright (c) 2005, 2006, 2007, 2008 Peter Palfrader <peter@palfrader.org>
#
# Permission is hereby granted, free of charge, to any person obtaining
# a copy of this software and associated documentation files (the
# "Software"), to deal in the Software without restriction, including
# without limitation the rights to use, copy, modify, merge, publish,
# distribute, sublicense, and/or sell copies of the Software, and to
# permit persons to whom the Software is furnished to do so, subject to
# the following conditions:
#
# The above copyright notice and this permission notice shall be
# included in all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
# EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
# MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
# NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
# LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
# OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
# WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

use strict;
use English;
use MIME::Base64;


my $HOME = '/home/commit/';
my $MAX_LINES = 4;
my $ENVELOPE_FROM = 'nobody@commit.noreply.org';
my $HEADER_FROM = 'nobody@commit.noreply.org';
my $BOT_ADDRESS = 'commit@commit.noreply.org';
my $SENDMAIL = '/usr/sbin/sendmail';

$ENV{'PATH'} = '/bin:/usr/bin';
delete @ENV{'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};

die ("Usage: $PROGRAM_NAME <project> <mailfile>\n") unless (scalar @ARGV == 2);
my $project = $ARGV[0];

umask 077;

$project =~ m/^([a-zA-Z-]+(\.[a-zA-Z-]+)*)+$/;
$project = $1;
die ("Project is not a nice name.\n") unless defined $project;

my $is_base64 = 0;

open (MAIL, $ARGV[1]) || die ("Cannot open $ARGV[1]: $!\n");
my @mail = <MAIL>;
close(MAIL);
my $line;

my @headers;
my $lastline = undef;
while (defined($line = shift @mail)) {
	my $chomped = $line;
	chomp $chomped;
	if ($chomped =~ m/^\s+/) {
		$lastline .= ' '.$line;
	} elsif ($chomped =~ m/^$/) {
		push @headers, $lastline if defined $lastline;
		push @headers, $line;
		push @headers, @mail;
		last
	} else {
		push @headers, $lastline if defined $lastline;
		$lastline = $line;
	}
}

my $is_a_reply;
my $tracproject;
my $ticketid;
my $url;

while (defined($line = shift @headers)) {
	if ($line =~ m/^Subject:/i) {
		$is_a_reply = ($line =~ m/^Subject:\s*Re:/i);
	} elsif ($line =~ m/^X-Trac-Project:\s*(.*)/i) {
		$tracproject = $1;
	} elsif ($line =~ m/^X-Trac-Ticket-URL:\s*(.*)/i) {
		$url = $1;
		#$url =~ s/^https:/http:/;
	} elsif ($line =~ m/^X-Trac-Ticket-ID:\s*(.*)/i) {
		$ticketid = $1;
	} elsif ($line =~ m/^Content-Transfer-Encoding: base64$/s) {
		$is_base64 = 1;
	} elsif ($line =~ m/^$/) {
		last;
	}
};

my $body = join '', @mail;
$body = decode_base64($body) if ($is_base64);
@mail = split(/\r?\n/, $body);

my @summary;
while (defined($line = shift @mail)) {
	last if $line =~ /^-----------------/;
	chomp $line;
	push @summary, $line;
};
my $summary = join ' ', @summary;

my $reporter;
while (defined($line = shift @mail)) {
	if ($line =~ /Reporter:\s*(.*?)\s*\|/i and not defined $reporter) {
		$reporter = $1;
	};
	last if $line =~ /^-----------------/
}
my @body;
while (defined($line = shift @mail)) {
	last if $line =~ /^--/;
	push @body, $line;
}

die ("$PROGRAM_NAME - $project: No reporter found.\n") unless defined $reporter;
die ("$PROGRAM_NAME - $project: No tracproject found.\n") unless defined $tracproject;
die ("$PROGRAM_NAME - $project: No url found.\n") unless defined $url;
die ("$PROGRAM_NAME - $project: No ticketid found.\n") unless defined $ticketid;
die ("$PROGRAM_NAME - $project: No summary found.\n") unless defined $summary;

my $MAXBODYLINES = 5;
if (scalar @body > $MAXBODYLINES+1) {      # if it's one more let it through, [...] takes a line too
	$body = join "\n", @body[0 .. $MAXBODYLINES-1];
	$body .= "[...]\n";
} else {
	$body = join "\n", @body;
};

my $notice = $is_a_reply ?
	"[$tracproject] #$ticketid was updated" :
	"[$tracproject] #$ticketid filed by $reporter";

$notice .= ":  $summary - $url";

#open(MAIL, "|cat") or
open(MAIL, "|$SENDMAIL -t -oi -f $ENVELOPE_FROM") or
	die ("Cannot exec sendmail: $!\n");
print MAIL "From: $HEADER_FROM\n";
print MAIL "To: $BOT_ADDRESS\n";
print MAIL "Subject: Announce $project\n";
print MAIL "Precedence: junk\n";
print MAIL "\n";
print MAIL "$notice\n";
print MAIL "$body\n";
close(MAIL);