#!/usr/bin/perl -Tw

# Copyright (C) 2006 Peter Palfrader <peter@palfrader.org>

# Need to allow /usr/local/bin/tw_cli info c0 u0 status in sudoers:
#
#  nagios          ALL=(ALL) NOPASSWD: /usr/local/bin/tw_cli info c0 u0 status
#

use strict;
use English;
use Getopt::Long;

$ENV{'PATH'} = '/bin:/sbin:/usr/bin:/usr/sbin';
delete @ENV{'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};

my $TW_CLI = 'sudo /usr/local/bin/tw_cli';
my $VERSION = '0.0.0';

# nagios exit codes
my $UNKNOWN = -1;
my $OK = 0;
my $WARNING = 1;
my $CRITICAL = 2;

my $params = {
	controller => 0,
	unit       => 0
	};

Getopt::Long::config('bundling');
if (!GetOptions (
	'--help'	=> \$params->{'help'},
	'--version'	=> \$params->{'version'},
	'--verbose'	=> \$params->{'verbose'},
	'--controller'	=> \$params->{'controller'},
	'--unit'	=> \$params->{'unit'},
	)) {
	die ("$PROGRAM_NAME: Usage: $PROGRAM_NAME [--help|--version] [--verbose]\n");
};
if ($params->{'help'}) {
	print "$PROGRAM_NAME: Usage: $PROGRAM_NAME [--help|--version] [--verbose]\n";
	print "Reports processes that are linked against libraries that no longer exist.\n";
	exit (0);
};
if ($params->{'version'}) {
	print "nagios-check-libs $VERSION\n";
	print "nagios check for availability of debian (security) updates\n";
	print "Copyright (c) 2005 Peter Palfrader <peter\@palfrader.org>\n";
	exit (0);
};

$SIG{'__DIE__'} = sub {
	print STDERR @_;
	exit $UNKNOWN;
};


my $command = "$TW_CLI info c$params->{'controller'} u$params->{'unit'} status";
print STDERR "Running $command\n" if $params->{'verbose'};
open (TW, "$command|") or die ("Cannot run $command: $!\n");
my @tw=<TW>;
close TW;
if ($CHILD_ERROR) { # program failed
	die("$command returned with non-zero exit code: ".($CHILD_ERROR / 256)."\n");
};


my $exit = $UNKNOWN;
my $msg = '';
for my $line (@tw)  {
	chomp $line;
	next if $line =~ /^$/;
	my ($device, $status) = $line =~ m#^(/c[0-9]+/u[0-9]+) status = ([A-Z]+)$#;
	unless (defined($device) && defined($status)) {
		print "Cannot parse line '$line'\n";
		exit $UNKNOWN;
	};
	if ($status eq 'OK') {
		$msg .= "$device: $status; ";
		$exit = $exit > $OK ? $exit : $OK;
	} elsif ($status eq 'DEGRADED') {
		$msg .= "$device: $status; ";
		$exit = $exit > $CRITICAL ? $exit : $CRITICAL;
	} elsif ($status eq 'OFFLINE') {
		$msg .= "$device: $status; ";
		$exit = $exit > $CRITICAL ? $exit : $CRITICAL;
	} else {
		$msg .= "$device: UKNOWN STATUS '$status'; ";
		$exit = $exit > $UNKNOWN ? $exit : $UNKNOWN;
	};
};

if ($msg eq '') {
	$msg = "No devices found";
	die ("exit is not UKNOWN but $exit") if ($exit != $UNKNOWN);
}

print $msg,"\n";
exit $exit;