#! /bin/false

if [ -e /etc/zsh/zshenv ]; then
 . /etc/zsh/zshenv
fi

HOSTNAME="`hostname`"
SYSTEM="`uname -s`"
ARCH="`uname -m`"

case "$TERM" in
	linux)	# Linux console
		bindkey '\e[1~' beginning-of-line	# Home 
		bindkey '\e[4~' end-of-line		# End  
		bindkey '\e[3~' delete-char		# Del
		bindkey '\e[2~' overwrite-mode		# Insert  
		;;
	screen) # The textmode window manager
		# In Linux console
		bindkey '\e[1~' beginning-of-line	# Home
		bindkey '\e[4~' end-of-line		# End  
		bindkey '\e[3~' delete-char		# Del
		bindkey '\e[2~' overwrite-mode		# Insert  
		bindkey '\e[7~' beginning-of-line	# home
		bindkey '\e[8~' end-of-line		# end
		# In rxvt
		bindkey '\eOc' forward-word		# ctrl cursor right
		bindkey '\eOd' backward-word		# ctrl cursor left
		bindkey '\e[3~' backward-delete-char	# This should not be necessary!
		;;
	rxvt)
		bindkey '\e[7~' beginning-of-line	# home
		bindkey '\e[8~' end-of-line		# end
		bindkey '\eOc' forward-word		# ctrl cursor right
		bindkey '\eOd' backward-word		# ctrl cursor left
		bindkey '\e[3~' backward-delete-char	# This should not be necessary!
		bindkey '\e[2~' overwrite-mode		# Insert
		;;
	xterm*)
		bindkey '\e[H' beginning-of-line	# Home
		bindkey '\e[F'  end-of-line		# End
		bindkey '\e[3~' delete-char		# Del
		bindkey '\e[2~' overwrite-mode		# Insert
		bindkey "^[[5C"   forward-word          # ctrl cursor right
		bindkey "^[[5D"   backward-word         # ctrl cursor left
		
		;;
	sun)
		bindkey '\e[214z' beginning-of-line       # Home
		bindkey '\e[220z' end-of-line             # End
		bindkey '^J'      delete-char             # Del
		bindkey '^H'      backward-delete-char    # Backspace
		bindkey '\e[247z' overwrite-mode          # Insert
		;;
esac




## Set options
setopt \
	extendedglob \
	list_types \
	nocorrect \
	list_ambiguous \
	bash_auto_list \
	list_packed \
	interactive_comments \
	nohup \
	autocd \
	CHECK_JOBS \
	BG_NICE \
	APPEND_HISTORY \
	INC_APPEND_HISTORY \
	HIST_IGNORE_DUPS \
	EXTENDED_GLOB \
	HIST_FIND_NO_DUPS \
	HIST_IGNORE_SPACE \

HISTFILE=~/.zsh_history
HISTSIZE=50000
SAVEHIST=50000


case $TERM in
	xterm*)
		precmd() {
			title=$TITLE
			#print -Pn "\e]2;$title\a\e]1;\a"
			print -Pn "\033]0;$title\007"
		};
		preexec() {
			title="$1 [$TITLE]"
			title=`echo $title | tr '\n' ' '`
			#print -Pn "\e]2;$title\a\e]1;\a"
			print -Pn "\033]0;$title\007"
		};
		;;
	screen*)
		if [ -x /usr/bin/screen ] || [ -x /usr/local/bin/screen ]; then
			if grep -i -q screen <<< $TERMCAP ; then
				precmd () {p=`print -Pn "%~"`; screen -X title "<$p>";}
				preexec () {p=`print -Pn "%~:$1"`; screen -X title "<$p>";}
			fi
		fi;
		;;
esac


## Export environment
if [ -x /usr/bin/lesspipe ] ; then
	eval `lesspipe`
fi

export DEBEMAIL="weasel@debian.org"


# in 'foo bar | baz' make a second ^W not eat 'bar |', but only '|'
# this has the disadvantage that in 'bar|baz' it eats all of it.
typeset WORDCHARS='|'$WORDCHARS

# malsync
if [ "$SYSTEM" = "Linux" ] ; then
	eval `dircolors`
	LS_COLORS="$LS_COLORS""*.divx=01;35:"

	alias ls='ls --color=auto -F'
	alias grep='grep --color'
fi
alias cp='cp -i'
alias mv='mv -i'

alias mmv='noglob mmv'

alias zinterdiff='interdiff -z'

alias defaultfixed='echo -n -e "\033]50;fixed\007"'
alias default='echo -n -e "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-70-iso8859-15\007"'
alias hide='echo -n -e "\033]50;nil2\007"'
alias tiny='echo -n -e "\033]50;-misc-fixed-medium-r-normal--7-70-75-75-c-50-iso8859-15\007"'
alias small='echo -n -e "\033]50;-misc-fixed-medium-r-normal--10-100-75-75-c-60-iso8859-15\007"'
alias medium='echo -n -e "\033]50;-misc-fixed-medium-r-normal--13-120-75-75-c-70-iso8859-15\007"'
alias large='echo -n -e "\033]50;-misc-fixed-medium-r-normal--15-140-75-75-c-90-iso8859-15\007"'
alias huge='echo -n -e "\033]50;-misc-fixed-medium-r-normal--20-200-75-75-c-100-iso8859-15\007"'

[[ -x /usr/sbin/traceroute ]] && alias traceroute=/usr/sbin/traceroute
[[ -x /sbin/ifconfig ]] && alias ifconfig=/sbin/ifconfig
[[ -x /sbin/route ]] && alias route=/sbin/route

if [ -x /usr/bin/recode ]; then
	alias unix2dos='recode lat1..ibmpc'
	alias dos2unix='recode ibmpc..lat1'
fi
[[ -x /usr/sbin/samhain ]] && alias samhain-check='sudo /usr/sbin/samhain -t check -i -p err -s none -l none -m none'

alias 221='pstops "2:0L@.7(21cm,0)+1L@.7(21cm,14.85cm)"'
alias rot13='tr a-zA-Z n-za-mN-ZA-M'
alias 64216='perl -MMIME::Base64 -e "print unpack(\"H*\", decode_base64(<>)),\"\n\""'
alias 16264='perl -MMIME::Base64 -e "\$l=<>; chomp \$l; print encode_base64(pack(\"H*\", \$l)),\"\n\""'

if [ -x /usr/bin/base64 ]; then
	alias base64-encode=base64
	alias base64-decode='base64 -d'
else
	alias base64-encode='perl -MMIME::Base64 -e "print encode_base64(<>)"'
	alias base64-decode='perl -MMIME::Base64 -e "print decode_base64(<>)"'
fi

alias vnc='xtightvncviewer -encodings "tight copyrect" -compresslevel 9 -quality 4'
alias rdesktop-w='rdesktop -x l -g 1280x1024 -a 16 172.22.118.112'


if [ -f ~/.ssh/alias ] ; then
	. ~/.ssh/alias
else
	if [ -f ~/.ssh/config ] ; then
		for i in `grep "^Host " ~/.ssh/config | awk ' !/\*/ {print $2}'`; do alias $i="ssh $i"; done
	fi
fi

if [ "$HOSTNAME" = 'thetis' ] ; then
	alias ldapvi='ldapvi --encoding=ASCII -h localhost -D cn=admin,o=ab.office.dibral.at -w `grep bindpw $HOME/.noreply.ldap | cut -d" " -f 2`'
fi
if [ "$HOSTNAME" = 'anguilla' ] && [ -r "$HOME/.oftc-hosts" ] ; then
	cat "$HOME/.oftc-hosts" | while read name ip; do
		alias -g $name-ip="$ip"
		alias irssi-$name="irssi --home=$HOME/.irssi-MASTER --connect=OFTC-$name"

		alias -g $name-testnet-ip="$ip"
		alias irssi-testnet-$name="irssi --home=$HOME/.irssi-MASTER --connect=TESTNET-$name"
	done
fi

if [ -e /etc/debian_chroot ]; then
	debian_chroot=$(cat /etc/debian_chroot)
fi

if [ "`id -u`" = "0" -o ! -x /usr/bin/id ] ; then
	export PROMPT="${debian_chroot:+[$debian_chroot] }%n@%m:%~# "
	export TITLE="%n@%m: %~"
else
	export PROMPT="${debian_chroot:+[$debian_chroot] }%n@%m:%~$ "
	export TITLE="%n@%m: %~"
fi



# SETUP PATH
############
path=(
	"$HOME/bin"
	"$HOME/local/bin"
	/usr/lib/ccache
	/usr/local/bin
	/usr/bin
	/bin
	/usr/bin/X11
	/usr/games
	/sw/bin
	"$path[@]"
)
if [ "`id -u`" = "0" ] || ! [ -x /usr/bin/id ] ; then
	PATH="/usr/local/sbin:/usr/sbin:/sbin:${PATH}"
	path=(
		/usr/local/sbin
		/usr/sbin
		/sbin
		"$path[@]"
	)
fi
export PATH
# Only unique entries please.
typeset -U path
# Remove entries that don't exist on this system.  Just for sanity's
# sake more than anything.
path=( ${^path}(N-/) )



#MANPATH="/usr/share/man:/usr/local/share/man:/usr/local/man:$MANPATH"
#if [ -d $HOME/local/share/man ] ; then
#	MANPATH="${HOME}/local/share/man:${MANPATH}"
#fi




# we want colorful listings
zmodload -i zsh/complist
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
hosts=""
if [ -e $HOME/.ssh/known_hosts ]; then
	hosts=(${${${${(f)"$(<$HOME/.ssh/known_hosts)"}:#[0-9]*}%%\ *}%%,*})
	zstyle ':completion:*:hosts' hosts $hosts
fi

autoload -U compinit
compinit

##########
upgrade-porter-chroots() {
	cd
	for i in $DEBPORTERHOSTS; do
		mkdir hosts/chroot-$i 2>/dev/null || continue;
		echo $i;
		preexec $i;
		ssh $i -t 'sudo /usr/sbin/upgrade-porter-chroots'
	done
}
upgrade-debian-hosts() {
	cd
	for i in $DEBHOSTS; do
		mkdir hosts/$i 2>/dev/null || continue;
		echo $i;
		preexec $i;
		ssh $i -t '
				sudo apt-get update &&
				sudo apt-get dist-upgrade &&
				sudo apt-get clean
			';
	done
}
upgrade-systems() {
	cd
	for i in $HOSTS; do
		mkdir hosts/$i 2>/dev/null || continue;
		echo $i;
		preexec $i;
		ssh $i -t 'apt-get update &&
			if [ -e /usr/bin/apt-get.distrib ]; then
				aptitude dist-upgrade;
			else
				apt-get dist-upgrade;
			fi &&
			apt-get clean';
	done
}
upgrade-debian-samhain() {
	for i in $DEBHOSTS; do
		mkdir hosts/$i 2> /dev/null || continue;
		echo $i
		preexec $i;
		ssh $i -t '
			didsudo=0
			check() {
				sudo /usr/sbin/samhain -t check -i -p err -s none -l none -m none
			};
			reinit() {
				if [ "`check 2>&1 | grep "^CRIT" | wc -l`" != 0 ]; then
					echo Updating samhain db...
					sudo samhain --foreground -t update
					didsudo=1
					echo done.
				fi
			}
			if [ -x /usr/sbin/samhain ]; then
				t="`tempfile`";
				trap "rm -f $t" 0 1 2 5 15;
				check > "$t" 2>&1;
				if [ "`grep "^CRIT" "$t" | wc -l`" != 0 ]; then
					echo "samhain db errors found:";
					sed -e "s/.*path=<\([^>]*\)>, .*/\1/" "$t";
					echo;
					echo "Enter 'y' to continue upgrade and update samhaindb for `hostname`";
					read ans;
					[ "$ans" = "y" ] || exit;
				fi;
			fi
			sudo apt-get update &&
			sudo apt-get dist-upgrade &&
			sudo apt-get clean &&
			[ -x /usr/sbin/samhain ] && reinit
			if [ "$didsudo" = 1 ]; then
				echo Updating nagios status
				echo "apt"
				sudo /usr/sbin/dsa-update-apt-status
				echo "samhain"
				grep -q OK /var/cache/dsa/nagios/samhain || sudo dsa-update-samhain-status
				echo done.
			fi
		';
	done
}

reinit-debian-samhain-one() {
	host=$1
	if [ "$host" = "${host%%.debian.org}" ]; then
		host="$host.debian.org"
	fi
	echo $host
	preexec $host;
	ssh $host -t '
		check() {
			sudo /usr/sbin/samhain -t check -i -p err -s none -l none -m none
		};
		if [ -x /usr/sbin/samhain ]; then
			t="`tempfile`";
			trap "rm -f $t" 0 1 2 5 15;
			check > "$t" 2>&1;
			if [ "`grep "^CRIT" "$t" | wc -l`" != 0 ]; then
				echo "samhain db errors found:";
				sed -e "s/.*path=<\([^>]*\)>, .*/\1/" "$t";
				echo;
				echo "Enter 'y' to continue upgrade and update samhaindb for `hostname`";
				read ans;
				[ "$ans" = "y" ] || exit;

				echo Updating samhain db...
				sudo samhain --foreground -t update
				grep -q OK /var/cache/dsa/nagios/samhain || sudo dsa-update-samhain-status
				echo done.
			fi;
		fi
	';
}
reinit-debian-samhain() {
	for i in $DEBHOSTS; do
		mkdir hosts/$i 2> /dev/null || continue;
		reinit-debian-samhain-one $i
	done
}

update-debian-exim() {
	for i in $DEBHOSTS; do
		mkdir hosts/$i 2> /dev/null || continue;
		echo $i
		preexec $i;
		ssh $i -t '
			[ -d /etc/exim4 ] || exit;
			cd /etc/exim4 &&
			sudo ./Git/bin/update &&
			sudo env -i /etc/init.d/exim4 reload
		';
	done
}

fpr() {
	 (
	 	ssh-keygen -r '' -f =( ssh-keyscan -t rsa $1 2>/dev/null | sed -e 's/^[^ ]* //');
		ssh-keygen -r '' -f =( ssh-keyscan -t dsa $1 2>/dev/null | sed -e 's/^[^ ]* //');
	) | sed -e 's/^[^ ]* //'
}

##########
md() {
	DIR="$1"
	mkdir "$1" && cd "$1"
}

#########
sd() {
	fp=$(   wget -q -O - http://tor.noreply.org:80/tor/status/authority | \
		awk '$1 == "r" && $2 == "'$1'" {printf "%s===", $3}' | \
		perl -MMIME::Base64 -e "print unpack(\"H*\", decode_base64(<>)),\"\n\"" )
	echo wget -q -O - http://tor.noreply.org:80/tor/server/fp/$fp
}



if [ -x /usr/bin/ddate ] ; then
	/usr/bin/ddate
	echo
fi

if [ -x /usr/games/fortune ]; then
	FORTUNE_PATH=""
	[ -d /usr/share/games/fortunes ] && FORTUNE_PATH="$FORTUNE_PATH /usr/share/games/fortunes"
	[ -d /usr/share/games/fortunes/off ] && FORTUNE_PATH="$FORTUNE_PATH /usr/share/games/fortunes/off"
	[ -d $HOME/.fortunes/ ] && FORTUNE_PATH="$FORTUNE_PATH $HOME/.fortunes/"
	fortune `echo $FORTUNE_PATH`
	echo
fi


#watch=( $(<~/.friends) ) # watch for people in .friends file
watch=(notme)             # watch for everybody but me
LOGCHECK=300              # check every 5 min for login/logout activity
WATCHFMT='%n %a %l from %m at %t.'

[ -f COMMANDMENTS ] && cat COMMANDMENTS

if [ "$SSH_AUTH_SOCK" != "" ] && [ "$SSH_AUTH_SOCK" != "$HOME/.ssh-auth-sock" ] ; then
	if ! [ -e "$HOME/.ssh-auth-sock" ] || [ "`readlink $HOME/.ssh-auth-sock`" != "$SSH_AUTH_SOCK" ]; then
		echo "Setting ~/.ssh-auth-sock."
		rm -f "$HOME/.ssh-auth-sock"
		ln -s "$SSH_AUTH_SOCK" "$HOME/.ssh-auth-sock"
	fi
elif [ "$SSH_AUTH_SOCK" = "" ] && [ -e "$HOME/.ssh-auth-sock" ]; then
	SSH_AUTH_SOCK="$HOME/.ssh-auth-sock"; export SSH_AUTH_SOCK
fi


alias hs-mplayer='mplayer -ao alsa:device=hw=1'

[ -e $HOME/.zshrc-local ] && . $HOME/.zshrc-local
[ -e $HOME/.pal ] && [ -e /usr/bin/pal ] && pal -r 5-10
unset LANG